（1）決定性述語: clpvar/1 

引数が制約変数のときに成功します。

（2）決定性述語: freeze/2 

変数が値を持った時に起動される遅延実行ゴールを設定します。
詳細は述語リファレンスをご参照ください。

ある変数が値を持った時に実行されるゴールは、同一変数に対して順次 freeze/2 で追加することができますが、遅延実行時においては決定性、すなわちゴール(列)の最後にカットオペレータがついたものになります。
デバッグモードで起動し、ある変数が値をもったときtraceを開始させるspyの変形（下記の例）のように、制約解消系以外の用途でも使うことができます。
＜例＞

|  ?-debug.
|| ?-freeze(X,trace),go(X).     % go(X) の実行の経過で、X が値を持ったときにtrace が開始される

（3）決定性述語: frozen/2 

変数（第１引数に指定）に設定さている遅延実行ゴールを第２引数とユニファイします。遅延実行機構はこの述語により遅延実行ゴールを取得します。また設定内容の確認にも用いることができます。
詳細は述語リファレンスをご参照ください。

（4）決定性述語: put_clp_area/2 

変数に値領域（領域制約）を設定します。既に値領域が設定されている場合はANDで追加されます。設定できる値は任意の項です。
第二引数はソートされていることが前提となる述語で、拡張ライブラリ組込述語「in /xfx」の下層述語（AZ-Prolog本体側に組み込まれた述語の意。単に領域制約を設定するだけで、ソートは上層側の責任において行う）となります。
＜例＞

| ?-put_clp_area(X,[1,2,5..7]),get_clp_area(X,L).
X       = X,
L       = [1,2,5..7]
yes
| ?-put_clp_area(X,[a,b,d,1,2,5..7]),put_clp_area(X,[b,2..6]),get_clp_area(X,L).
no
% アトムは数値より大きいので、つぎのようにソートして領域設定する。
| ?-put_clp_area(X,[1,2,5..7,a,b,d]),put_clp_area(X,[2..6,b]),get_clp_area(X,L).
X       = _43,
L       = [2,5,6,b]
yes

（5）決定性述語: rm_clp_area/2 

既に値領域が設定されている変数から指定領域を取り除きます。
拡張ライブラリ組込述語「notin /xfx」の下層述語です。
＜例＞

| ?-put_clp_area(X,[1..9]),rm_clp_area(X,4..7),get_clp_area(X,L). 
X       = X,
L       = [1..3,8,9]
yes

（6）決定性述語: get_clp_area/2 

変数に値領域が設定されている場合、その設定領域を取得します。呼び出し時点で既に変数の値が決定している（既に変数ではない）場合は失敗します。
拡張ライブラリ組込述語「indomain/1」などの下層述語です。
＜例＞

| ?-X in 0..9,get_clp_area(X,L).
X       = X,
L       = [0..9]
yes

（7）決定性述語: clp_intersection/3 

「put_clp_area/2」の補助述語(汎用)で、２集合の共通部分を取得します。
＜例＞

| ?-clp_intersection([1,3..6,9..12],[2..11],L).
L       = [3..6,9..11]
yes

（8）決定性述語: clp_is_member/2 

「put_clp_area/2」「in /xfx」の補助述語で第一引数が第二引数のリストに含まれる場合成功します。
＜例＞

| ?- clp_is_member(a,[1..9,b,c(z)]).
no
| ?- clp_is_member(a,[1..9,a,c(z)]).
yes
| ?- clp_is_member(7,[1..9,a,c(z)]).
yes

（9）決定性述語: system_get_min_max_int/2 

処理系で扱う整数の下限と上限を取得します。
＜例＞

| ?- system_get_min_max_int(MinInt,MaxInt).
MinInt  = -9223372036854775808,
MaxInt  = 9223372036854775807
yes

（10）決定性述語: s_constraints_mode/2 

A1,A2ともonまたはoff
A1 現在の制約マクロ展開モード
A2 設定する制約マクロ展開モード

モードがonのとき、読み込みにおいて制約マクロ記述を展開して(変数に制約を付与して）読込みます。

読み込んだ項に含まれる制約記述をすべて実行するので、そのままアサートされることは前提としません。off のときは入力どおりの内容で読込みます。
＜例＞

?- s_constraints_mode(_,on).
(1) TopLevelでの入力

| ?- X={a:A#(A=B),b:B}.
X = {a:_2,b:_4}        % _2は _2=_4に制約されている
yes

| ?- X={a:A#(A=B),b:B},X={a:aa}.
X = {a:aa,b:aa}
yes 

(2) Read系
read/1,read/2,d_read/2,d_read/3

| ?- read(X),X=a(1,C).
|: a(A#(B is A+2) , B). 
X = a(1,3)
C = 3
yes

(3) 内部でReadを利用している述語
term_atom/2(atom->termのみ),term_string/2(string->termのみ),redis_command_to_term/4
＜term_atomの例＞

| ?- term_atom(T,'a(A#(B is A+2) , B)'),T=a(3,Y).
T = a(3,5)
Y = 5
yes

＜Redis を使う例＞

:- dlib_require(redis).
test_fs_macro(V):-
       redis_connect('127.0.0.1',6379,3000,CON),                         % Redisコネクト
       redis_command(CON,[set,'mykey1',{a:X#[1,2,3],b:Y#(X=Y) }],_,_),   % 辞書セット 
       s_constraints_mode(OnOff,on),                                     % マクロ展開モードに切替
           errorset(redis_command_to_term(CON,'get mykey1',_,V),Err),!,  % 辞書読み込み
       s_constraints_mode(_,OnOff),                                      % マクロ展開モードを戻す
       redis_free_context(CON),                                          % Redisコネクションを切る
       Err=succ.
 
 | ?- X= {b:2},test_fs_macro(X).
 X = {b:2,a:2}
 yes

次の述語においては従来どおりの動作である。
consult/1,reconsult/1,e_consult/0,e_reconsult/0
ファイルに制約マクロが記述されていて、それを活かしたい場合は後述する macro_consult/1を使用する。

（11）決定性述語: is_clp_macro_exist/2 

A1,A2ともonまたはoff
A1 直前のRead（TopLevel含む）にマクロ制約変数が含まれていたとき、自動でonとなります。
A2 on/offを再設定します。
s_constraints_modeの如何に関わらずフラグが自動セットされます。
＜例＞

| ?-s_constraints_mode(F,F).
F     = off
yes
| ?-read(X),is_clp_macro_exist(F,F).
|: a(A#(A=B),B). 
X       = a(A_31#(A_31=B_33),B_33),
F       = on
yes
| ?-read(X),is_clp_macro_exist(F,F).
|: a(A,B).
X       = a(A_25,B_27),
F       = off
yes
| ?-s_constraints_mode(_,on).
_.2     = off
yes
| ?-read(X),is_clp_macro_exist(F,F).
|: a(A#(A=B),B).
X       = a(_35,B_33),
F       = on
yes

（12）決定性述語: macro_consult/1 

コンパイル組み込み述語：ソース $(AZPROLOG)/system/pl/macro_consult.pl

マクロ制約記述を展開してコンサルトします。
head 部に含まれているマクロはneck部に、Goal部に含まれているマクロはそのGoal直前に,freeze/2,put_clp_area/2として変換挿入されます。
＜例＞

‹file›
a({が格:X#eat(X,Y),を格:Y}).

eat(猫,ネズミ).
eat(ネズミ,チーズ).

  | ?- macro_consult(file).
  yes
  | ?- X={が格:ネズミ},a(X).
  X = {が格:ネズミ,を格:チーズ}
  yes

  | ?- listing(a).    %   Macro展開       
a({が格:X,を格:Y},A):- freeze(X,eat(X,Y)).


・ファイルコンサルト時にエラーが発生した場合、その場所を知るにはechoモードをonにしてからコンサルトするとわかりやすい。
  | ?-echo(_,on),macro_consult(file).

・AZEditバッファからのマクロ展開コンサルト方法
  | ?- e_jump(0),e_markend,macro_consult(edit).

・コンソール直接入力のマクロ展開コンサルト方法
  | ?-macro_consult(user).    
  |: a(X#(X=Y),Y).
  終了は Windows コントロールZ、Linux コントロールD
  
・複数の変数が相互に関係する制約マクロの記述例
  ＜ファイル test.pl＞
  a(A#test(A,B,C,D, Z), B#test(A,B,C,D, Z)  ,C#test(A,B,C,D, Z) ,D#test(A,B,C,D, Z),  Z).
　test(A,B,C,D,  Z):- nonvar(A),nonvar(B),nonvar(C),nonvar(D),Z is A+B+C+D.
　test(_,_,_,_,  _).

  ＜実行＞
　?- macro_consult('test.pl').
　yes
　?- a(1,2,3,4,Ans).
　Ans = 10
　yes
　?- a(A,B,C,D,Ans),D=1,A=2,C=3,B=4.
　Ans = 10
　yes

| ?- dlib_require(clp).   

（1）決定性述語: in /xfx 

変数が取り得る値領域の制約（値のリスト）を与えます。
詳細は述語リファレンスをご参照ください。

（2）決定性述語: notin /xfx 

変数が取り得ない値領域（値のリスト）の制約を与えます。
詳細は述語リファレンスをご参照ください。

（3）決定性述語: alldifferent/1

引数リストに含まれる変数はすべて異なる値を持つという制約を与えます。
詳細は述語リファレンスをご参照ください。

（4）非決定性述語: indomain/1 

制約変数の取りうる値を非決定的にユニファイします。
詳細は述語リファレンスをご参照ください。

（5）非決定性述語: labeling/1 

与えられた制約に基づいて探索を行います。
詳細は述語リファレンスをご参照ください。

（6）決定性述語: #= /xfx

演算子の左右の数(式)の計算結果が等しいという制約を与えます。

（7）決定性述語: #¥= /xfx

演算子の左右の数(式)の計算結果が等しくないという制約を与えます。

（8）決定性述語: #< /xfx

演算子の右の数(式)の計算結果が左の数(式)の計算結果より大きいという制約を与えます。

（9）決定性述語: #> /xfx

演算子の左の数(式)の計算結果が右の数(式)の計算結果より大きいという制約を与えます。

（10）決定性述語: #=< /xfx

演算子の右の数(式)の計算結果が左の数(式)の計算結果より大きいか等しいという制約を与えます。

（11）決定性述語: #>= /xfx

演算子の左の数(式)の計算結果が右の数(式)の計算結果より大きいか等しいという制約を与えます。

[ _,  1,    _,  _,
_,  _,    2,  _,
3,  _,    _,  _,
_,  _,    _,  4]

:- dlib_require(clp).   % 拡張ライブラリをロードします

go:-     % ４x４の変数領域を作ります。マス目を左上から順に異なる変数で埋めます
     Vars = [X1, X2,  X3, X4,
             X5, X6,  X7, X8,
             X9, X10, X11,X12,
             X13,X14, X15,X16], 

      % ヒントとユニフィケーションして確定値を埋めます
      X2=1,X7=2,X9=3,X16=4,

      % 各変数は１から４までの数値が入るという制約を与えます
      Vars in 1..4 ,

     % 各行に含まれる変数はすべて異なる値を持つという制約を与えます
     alldifferent([X1, X2,  X3, X4]),
     alldifferent([X5, X6,  X7, X8]),
     alldifferent([X9, X10, X11,X12]),
     alldifferent([X13,X14, X15,X16]), 

     % 各列に含まれる変数はすべて異なる値を持つという制約を与えます
     alldifferent([X1,X5,X9,X13]),
     alldifferent([X2,X6,X10,X14]),
     alldifferent([X3,X7,X11,X15]),
     alldifferent([X4,X8,X12,X16]),

     % 各ブロックに含まれる変数はすべて異なる値を持つという制約を与えます
     alldifferent([X1,X2,X5,X6]),
     alldifferent([X3,X4,X7,X8]),
     alldifferent([X9,X10,X13,X14]),
     alldifferent([X11,X12,X15,X16]),

     % 以上の制約で探索を行います
     labeling(Vars),

     % 結果を表示します。
     write([[X1,X2],  [X3,X4]]),nl,
     write([[X5,X6],  [X7,X8]]),nl,nl,
     write([[X9,X10], [X11,X12]]),nl,
     write([[X13,X14],[X15,X16]]),nl.



| ?- go.
[2,1] [4,3]
[4,3] [2,1]

[3,4] [1,2]
[1,2] [3,4]

yes

※「数独（スウドク）」はニコリの登録商標(第3327502号など)で、日本では「ナンバープレース」と呼ばれることも多い。日本以外の国ではSudokuという呼称が一般的。

魔方陣とは正方形に並んだマスに、各列（縦）/各行（横）/両対角線のいずれの合計も同じになるように数字が並んだものを言います。
ここでは3X3魔方陣の解法を説明します。
使われる制約組込述語は「in /xfx」「alldifferent/1」「labeling/1」「#= /xfx」の4述語です。

なお、「sample/clp/magic.pl」では、NxNマスの魔方陣が解けるようになっています。
比較のため、このファイルには通常のPrologコードの生成検査法によるプログラムも収められています。
生成検査法では、4Ｘ4魔方陣においては16の階乗＝20兆とおりの組み合わせを試すことになり、最初の解を得るのでさえ相当の時間を要しますが、制約論理プログラミングでは、数分のうちに全解を求めることができます。
ただし、N＝6以上では第一解でさえ相当の時間を要します。

:- dlib_require(clp).     % 拡張ライブラリをロードします
go:-
    Vars = [X1,X2,X3,     % 変数領域を設定します
            X4,X5,X6,
            X7,X8,X9],
    Vars in 1..9,         % 各変数は１から９までの数値が入るという制約を与えます
    alldifferent(Vars),   % 各変数はすべて異なる値をとるという制約を与えます
    15 #= X1+X2+X3,       % 第１行のマスの合計値が１５になるという制約を与えます
    15 #= X4+X5+X6,       % 第２行のマスの合計値が１５になるという制約を与えます
    15 #= X7+X8+X9,       % 第３行のマスの合計値が１５になるという制約を与えます
    15 #= X1+X4+X7,       % 第１列のマスの合計値が１５になるという制約を与えます
    15 #= X2+X5+X8,       % 第２列のマスの合計値が１５になるという制約を与えます
    15 #= X3+X6+X9,       % 第３列のマスの合計値が１５になるという制約を与えます
    15 #= X1+X5+X9,       % 左上右下対角線のマスの合計値が１５になるという制約を与えます
    15 #= X3+X5+X7,       % 右上左下対角線のマスの合計値が１５になるという制約を与えます
    labeling(Vars),       % 以上の制約で探索を行います
    write([X1,X2,X3]),nl, % 結果を表示します。
    write([X4,X5,X6]),nl,
    write([X7,X8,X9]),nl. 

| ?-go.
[2,7,6]
[9,5,1]
[4,3,8]
yes

:- dlib_require(clp).              % 拡張ライブラリをロードします
go:-
    Vars = [S,E,N,D,M,O,R,Y],      % 変数領域を設定します
    Vars in 0..9,                  % 各変数は０から９までの数値が入るという制約を与えます
    alldifferent(Vars),            % 各変数はすべて異なる値をとるという制約を与えます
    S #¥= 0,                       % S は０ではないという制約を与えます
    M #¥= 0,                       % M は０ではないという制約を与えます
            S*1000+E*100+N*10+D    % SEND+MORE=MONEY であるという制約を与えます
           +M*1000+O*100+R*10+E
 #= M*10000+O*1000+N*100+E*10+Y,
    labeling(Vars),                % 以上の制約で探索を行います
    write(Vars),nl.                % 結果を表示します。

| ?-go.
[9,5,6,7,1,0,8,2]
yes

|?-listing.
turukame(Turu,Kame,Foot,Head) :-
    Turu in 0..Head,
    Kame in 0..Head,
    Foot#=Turu*2+Kame*4,
    Head#=Turu+Kame.
yes
|?-trace.
yes
||?-turukame(X,Y,14,5).
 [1] 0 Try   : turukame(X_7,Y_9,14,5) ?
  Match   : turukame(X_7,Y_9,14,5) :-
                X_7 in 0..5,
                Y_9 in 0..5,
                14#=X_7*2+Y_9*4,
                5#=X_7+Y_9.
 [2] 1 Try   : X_7 in 0..5 ? i           % Iコマンド
        Foot     = 14                    % 定義節の変数:Foot は 14に束縛されています
        Head     = 5                     % 定義節の変数:Head は 5に束縛されています
 [2] 1 Try   : X_7 in 0..5 ?
 ‹‹ BUILTIN CALL ››
 [2] 1 Succ  : _30 in 0..5
 [2] 1 Try   : Y_9 in 0..5 ? i           % Iコマンド
        Turu     = _30 { [0..5]::true }  % 定義節の変数:Turu は 0..5 に制約されています
        Foot     = 14
        Head     = 5
 [2] 1 Try   : Y_9 in 0..5 ?
 ‹‹ BUILTIN CALL ››
 [2] 1 Succ  : _46 in 0..5
 [2] 1 Try   : 14#=_30*2+_46*4 ? i       % Iコマンド
        Turu     = _30 { [0..5]::true }
        Kame     = _46 { [0..5]::true }
        Foot     = 14
        Head     = 5
 [2] 1 Try   : 14#=_30*2+_46*4 ?
 ‹‹ BUILTIN CALL ››
 [2] 1 Succ  : 14#=_30*2+_46*4
 [2] 1 Try   : 5#=_30+_46 ? i            <== Iコマンド
        Turu     = _30 { [1,3,5]::$clp_area_propagation(7,[1,2],[_30,_46]),! }   % 制約が狭まりました
        Kame     = _46 { [1..3]::$clp_area_propagation(7,[1,2],[_30,_46]),! }    % 制約が狭まりました
        Foot     = 14
        Head     = 5
 [2] 1 Try   : 5#=_30+_46 ?
 ‹‹ BUILTIN CALL ››
 [2] 1 Succ  : 5#=3+2                    % この制約で値が求まりました
 ‹‹ LAST CALL ››
 [1] 0 Succ  : turukame(3,2,14,5)
X       = 3,
Y       = 2
yes